Utilizar una imagen plana como textura para una esfera.

[ludovico]

En el recien concluido Astromartos 2008 surgió este tema y nuestro brillante conferenciante explicó varios modos de hacer esto.
Os presento un método alternativo, es este caso utilizando Pov-Ray.

Pov-Ray es gratuito, te lo puedes bajar en (povray.org), se basa en la tecnica del trazado de rayos, es decir, simular el comportamiento de los fotones desde la fuente de luz, rebotando en los objetos y terminando finalmente en nuestro ojo. El resultado, imágenes fantásticas (a veces hiperrealistas).

Cuando lo tengas instalado puedes correr el siguiente script:

#version 3.6;

#include "colors.inc"

global_settings {
assumed_gamma 1.0
}

// ----------------------------------------

camera {
location <0.0, 0.5, -4.0>
direction 1.5*z
right x*image_width/image_height
look_at <0.0, 0.0, 0.0>
}

sky_sphere {
pigment {
gradient y
color_map {
[0.0 rgb <0.6,0.7,1.0>]
[0.7 rgb <0.0,0.1,0.8>]
}
}
}

light_source {
<0, 0, 0> // light's position (translated below)
color rgb <1, 1, 1> // light's color
translate <-30, 30, -30>
}

// ----------------------------------------
#declare X=clock*360;

plane {
y, -1
pigment { color rgb <0.7,0.5,0.3> }
}

sphere {
0.0, 1
texture {
pigment {
image_map {
png "world.png" // the file to read (iff/tga/gif/png/jpeg/tiff/sys)
map_type 1 // 0=planar, 1=spherical, 2=cylindrical, 5=torus
interpolate 2 // 0=none, 1=linear, 2=bilinear, 4=normalized distance
}
}
}
rotate y*X
}
// Fin del script

Sustituye world.png por tu propia imagen (guarda la imagen y el script en la misma carpeta) , pulsa render y tendrás una esfera con la misma imagen como textura en tu carpeta de salida.

Si deseas crear un gif con la esfera rotando puedes establecer Final_Frame=xxx en command line options, donde xxx es el numero de imagenes que deseas obtener. (Cada una de las cuales estará rotada en xxx fracciones de 360). Las xxx imagenes resultantes las debes procesar porteriormente para crear el gif. (Adobe Imageready vale).

Esta técnica la he utilizado para el gif de una de mis páginas como podeis ver aqui :http://enciclopediadelinares.com

--------------
Saludos
Jesús